0 image.show

: rshift dup begin while 1 - swap 2 / swap dup repeat drop ;
: putpixel 0 image.pixel ;

: coz abs 2 * 64 - abs 2 * 64 - ;

256 constant WIDTH
176 constant HEIGHT
5 constant BITS
1 BITS lshift constant STEP
STEP 1 - constant MASK

create Map
0x00000 , 0xFFFFE , 0xAAAAA , 0xFFFFE , 0xFC9FE , 0xFDDFE , 0xFF7FE ,
0xFDDFE , 0xFC9FE , 0xFFFFE , 0xAAAAA , 0xFFFFE , 0x00000 ,

variable Swing
variable LocX variable LocY
variable Angle

create CosTable 256 cells allot

: init
   1 Angle !
   41 LocX !
   41 LocY !
   147 Swing !
   256 dup begin while 1 - dup coz over cells CosTable + ! dup repeat drop
;

: cos Angle @             cells CosTable + @ ;
: sin Angle @ 16 - 63 and cells CosTable + @ ;

variable dist
variable color
variable x variable y


variable h
variable j1
variable j2

: span
   color ! dist ! x !
   HEIGHT dist @ STEP WIDTH * HEIGHT / > if STEP WIDTH * HEIGHT / * dist @ / then h !
   HEIGHT h @ - 2 / j1 !
   j1 @ h @ + j2 !
   HEIGHT dup begin while 1 -
      x @ over
      dup j2 @ > if 0xFFFFFF else dup j1 @ < if 0 else color @ then then
      putpixel
   dup repeat drop
;

variable i0 variable j0
variable u0 variable v0
variable vx variable vy
variable da variable db
variable a  variable b
variable u  variable v
variable u1 variable v1
variable a1 variable b1
variable i  variable j
variable di variable dj
variable wall

: scan
   v @ u @ < dup if
      y @ STEP + y !
      u @ v @ - u !
      v1 @ v !
      j @ dj @ + j !
   else
      x @ STEP + x !
      v @ u @ - v !
      u1 @ u !
      i @ di @ + i !
   then
   wall !
;

: calc
   1 a @ 0 < if negate u0 @ a @ negate else STEP u0 @ - a @ then a1 ! u ! di !
   1 b @ 0 < if negate v0 @ b @ negate else STEP v0 @ - b @ then b1 ! v ! dj !
   u @ dup STEP - x ! b1 @ dup BITS lshift u1 ! * u !
   v @ dup STEP - y ! a1 @ dup BITS lshift v1 ! * v !
   i0 @ i !
   j0 @ j !

   1 begin while
      scan
   Map i @ cells + @ 1 j @ lshift and repeat

   dup
   wall @ if b1 y else a1 x then @ 18 lshift swap @ /
   i @ j @ + 3 and if 0x7F7F7F else 0x3F3F3F then span

   a @ da @ + a !
   b @ db @ - b !
;

: scene
   0 image.hide

   LocX @ dup BITS rshift i0 ! MASK and u0 !
   LocY @ dup BITS rshift j0 ! MASK and v0 !
   cos 10 lshift vx !
   sin 10 lshift vy !
   vy @ 128 / Swing @ * WIDTH / da !
   vx @ 128 / Swing @ * WIDTH / db !
   vx @ Swing @ vy @ 256 / * - a !
   vy @ Swing @ vx @ 256 / * + b !

   WIDTH dup begin while 1 -
      calc
   dup repeat drop

   0 image.show
   10 10 WIDTH HEIGHT 0 image.rect
;

: turn mouse.x 4 / 63 and Angle ! ;
use turn to mouse.move

variable forward

: start 1 forward ! ;
use start to mouse.left.down

: stop 0 forward ! ;
use stop to mouse.left.up

: run
   forward @ if
      LocX @ cos 16 / + dup x ! BITS rshift i !
      LocY @ sin 16 / + dup y ! BITS rshift j !
      Map i @ cells + @ 1 j @ lshift and if x @ LocX ! y @ LocY ! then
   then
;

: render run run run scene ;

init
40 timer.interval
use render to timer