0 VALUE OK 0 VALUE BEG 0 VALUE SRC 0 VALUE LIM
: `` ( a u -- ) OK IF LIM SRC - OVER DUP >R MIN SRC SWAP COMPARE
  IF FALSE TO OK R> DROP ELSE R> SRC + TO SRC THEN THEN ;
: ` ( string` -- ) [CHAR] ` PARSE POSTPONE SLITERAL POSTPONE `` ; IMMEDIATE
: .. ( c1 c2 -- ) OK IF SRC DUP LIM < IF C@ ELSE DROP 0 THEN
  -ROT 1+ WITHIN IF SRC CHAR+ TO SRC ELSE FALSE TO OK THEN ELSE 2DROP THEN ;
:NONAME DUP TO SRC TRUE TO OK ;
: | ( -- ) 1+ POSTPONE OK POSTPONE 0= POSTPONE IF LITERAL COMPILE, ; IMMEDIATE
: (( ( -- ) 0 POSTPONE OK POSTPONE IF POSTPONE SRC ; IMMEDIATE
:NONAME OK IF DROP ELSE TO SRC THEN ;
: )) ( -- ) 0 ?DO POSTPONE THEN LOOP LITERAL COMPILE, POSTPONE THEN ; IMMEDIATE
:NONAME OK IF >R SRC OVER - R> 2! ELSE DROP TO SRC THEN ;
: !)) ( d-addr -- ) 0 ?DO POSTPONE THEN LOOP LITERAL COMPILE, POSTPONE THEN ; IMMEDIATE
: {{ ( min max -- ) POSTPONE OK POSTPONE -ROT 0 POSTPONE LITERAL POSTPONE BEGIN POSTPONE (( ; IMMEDIATE
:NONAME NIP OK IF > 0= TO OK DROP ELSE DROP 0= IF TO OK ELSE DROP THEN THEN ;
:NONAME 1+ 2DUP = IF TRUE ELSE OK 0= THEN ;
: }} POSTPONE )) LITERAL COMPILE, POSTPONE UNTIL LITERAL COMPILE, ; IMMEDIATE
: EOL OK IF SRC LIM < 0= TO OK THEN ;
: ?WORD ( c -- f ) DUP [CHAR] A [CHAR] [ WITHIN OVER [CHAR] A [CHAR] { WITHIN OR
  SWAP [CHAR] 0 [CHAR] : WITHIN OR ;
: ?BOUND ( -- f ) SRC BEG > SRC CHAR+ LIM < AND
   IF SRC C@ ?WORD DUP SRC 1 - C@ ?WORD XOR IF DROP TRUE ELSE SRC CHAR+ C@ ?WORD XOR THEN ELSE TRUE THEN ;
: ?B OK IF ?BOUND TO OK THEN ;
: ^B OK IF ?BOUND 0= TO OK THEN ;
:NONAME ( c-addr u -- ) OVER + TO LIM DUP TO BEG TO SRC TRUE TO OK ;
: RX: : LITERAL COMPILE, POSTPONE (( ;
: ;RX POSTPONE )) POSTPONE OK POSTPONE ; ; IMMEDIATE