REQUIRE CASE    lib\ext\case.f
REQUIRE /STRING lib\include\string.f

\ Синтаксические символы :
0 CONSTANT null   \ неизвестный символ
1 CONSTANT plus
2 CONSTANT minus
3 CONSTANT star
4 CONSTANT slash
5 CONSTANT lparen
6 CONSTANT rparen
7 CONSTANT number
8 CONSTANT eot    \ конец входного потока или нулевая литера в нем

VARIABLE  STREAM \ указатель на текущую литеру входного потока
VARIABLE #STREAM \ число неразобранных литер во входном потоке
VARIABLE ch      \ прочитанная из входного потока литера
VARIABLE sym     \ прочитанный из входного потока синтаксический символ
VARIABLE val     \ прочитанное из входного потока число

: Error
  ( n --)
  CASE
    0 OF ." Too big number" ENDOF
    1 OF ." ) expected"     ENDOF
    2 OF ." Wrong syntax"   ENDOF
  ENDCASE
  CR BYE
;

: Read \ чтение литеры из входного потока
  #STREAM @ DUP IF 1- #STREAM ! STREAM @ C@ STREAM 1+! THEN ch !
;

: Number \ извлечение из входного потока числа val
  ( n -- )
  val !
  BEGIN
    Read ch C@
    10 DIGIT
  WHILE
    0 val @ 10 UM* D+ IF 0 Error THEN val !
  REPEAT
;
: Get \ чтение синтаксического символа из входного потока
  BEGIN
    ch C@ 1- BL U<
  WHILE
    Read
  REPEAT
  ch C@
  CASE
    0 OF eot ENDOF
    [CHAR] + OF Read plus   ENDOF
    [CHAR] - OF Read minus  ENDOF
    [CHAR] * OF Read star   ENDOF
    [CHAR] / OF Read slash  ENDOF
    [CHAR] ( OF Read lparen ENDOF
    [CHAR] ) OF Read rparen ENDOF
    10 DIGIT TRUE OF Number number ENDOF
    null SWAP
  ENDCASE
  sym !
;

VECT @выражение

: множитель
  sym @
  CASE
    number OF val @ Get ENDOF
    lparen OF Get @выражение sym @ rparen - IF 1 Error THEN Get ENDOF
    2 Error
  ENDCASE
;

: слагаемое
  множитель
  BEGIN
    sym @
    CASE
      star  OF Get множитель * ENDOF
      slash OF Get множитель / ENDOF
      DROP EXIT
    ENDCASE
  AGAIN
;

: выражение
  sym @
  CASE
    plus  OF Get слагаемое        ENDOF
    minus OF Get слагаемое NEGATE ENDOF
    DROP слагаемое 0
  ENDCASE
  BEGIN
    sym @
    CASE
      plus  OF Get слагаемое + ENDOF
      minus OF Get слагаемое - ENDOF
      DROP EXIT
    ENDCASE
  AGAIN
;
' выражение TO @выражение

: CALCULATE
  SOURCE >IN @ /STRING #STREAM ! STREAM !
  Read Get выражение
  sym @ eot - IF 2 Error THEN . CR
  [COMPILE] \
;

CALCULATE 7 + 3 * (5 - 1) / 2
CALCULATE -7 + 3 * (5 - 1) / 2

BYE

: BAD ." Wrong syntax" BYE ;

: (GET) 0 HERE C! HERE 1 H-STDIN READ-FILE 2DROP ;
: SEPARATOR? ( -- flag ) HERE C@ 1- BL U< ;
: GET
  BEGIN
    (GET) SEPARATOR? 0=
  UNTIL
;

VECT (EXPRESSION)
: FACTOR
  HERE C@ 10 DIGIT
  IF
    BEGIN
      (GET) HERE C@ 10 DIGIT
    WHILE
      SWAP 10 * +
    REPEAT
    SEPARATOR? IF GET THEN
  ELSE
    HERE C@ [CHAR] ( - IF BAD THEN
    GET (EXPRESSION)
    HERE C@ [CHAR] ) - IF BAD THEN
    GET
  THEN
;

: TERM
  FACTOR
  BEGIN
    HERE C@ [CHAR] * =
    IF
      ['] *
    ELSE
      HERE C@ [CHAR] / =
      IF
        ['] /
      ELSE
        EXIT
      THEN
    THEN
    >R GET FACTOR R> EXECUTE
  AGAIN
;

: EXPRESSION
  HERE C@ [CHAR] - =
  IF
    GET TERM NEGATE
  ELSE
    HERE C@ [CHAR] + = IF GET THEN
    TERM
  THEN
  BEGIN
    HERE C@ [CHAR] + =
    IF
      ['] +
    ELSE
      HERE C@ [CHAR] - =
      IF
        ['] -
      ELSE
        EXIT
      THEN
    THEN
    >R GET TERM R> EXECUTE
  AGAIN
;
' EXPRESSION TO (EXPRESSION)

: MAIN
  H-STDIN FILE-SIZE NIP NIP 0= IF GET EXPRESSION HERE C@ IF BAD THEN . THEN
;

' NOOP MAINX ! ' MAIN TO <MAIN> S" CalcArithm.Exe" SAVE BYE