KEY:      lrw   r12,   [_UART_]   // KEY      CORE
      subi   r0,   4
      ldb   r13,   (r12)      // tail
      stw   r14,   (r0)
_KEY:      ldb   r14,   (r12, 1)   // head
      cmpne   r13,   r14
      bf   _KEY
      bseti   r13,   20
      ldb   r14,   (r13)
      addi   r13,   1
      andi   r13,   0x1F
      stb   r13,   (r12)
      NEXT

KEY_QUESTION:   lrw   r13,   [_UART_]   // KEY?      FACILITY
      subi   r0,   4
      ldb   r12,   (r13)      // tail
      stw   r14,   (r0)
      xor   r14,   r14
      ldb   r13,   (r13, 1)   // head
      cmpne   r12,   r13
      dect   r14
      NEXT

// : ACCEPT ( c-addr +n1 -- +n2 )
//   OVER + OVER
//   BEGIN
//      KEY DUP >R
//      CASE
//        8 OF
//            2 PICK OVER <> IF R@ EMIT SPACE R@ EMIT 1- THEN
//          ENDOF
//        13 OF
//             RDROP CR NIP SWAP - EXIT
//           ENDOF
//        DUP BL U< INVERT
//        IF
//          2DUP <> IF R@ EMIT R@ OVER C! CHAR+ THEN
//        THEN
//      ENDCASE
//      RDROP
//   AGAIN
// ;
// Ввести строку максимальной длины до +n1 символов.
// Исключительная ситуация возникает, если +n1 0 или больше 32767.
// Отображать символы по мере ввода.
// Ввод прерывается, когда получен символ "конец строки".
// Ничего не добавляется в строку.
// +n2 - длина строки, записанной по адресу c-addr.
ACCEPT:      THREAD            // ACCEPT   CORE
      .long   OVER, PLUS, OVER
_ACCEPT:   .long   KEY, DUPE, TO_R
      .long   LIT, 8, NOT_EQUALS
      .long   QUESTION_BRANCH, ___ACCEPT
      .long   R_FETCH, LIT, 13, NOT_EQUALS
      .long   QUESTION_BRANCH, ____ACCEPT
      .long   TWO_DUPE, NOT_EQUALS
      .long   R_FETCH, BL, U_LESS_THAN, INVERT, AND
      .long   QUESTION_BRANCH, __ACCEPT
      .long   R_FETCH, EMIT, R_FETCH, OVER, C_STORE, ONE_PLUS
__ACCEPT:   .long   R_DROP
      .long   BRANCH, _ACCEPT
___ACCEPT:   .long   TWO, PICK, OVER, NOT_EQUALS
      .long   QUESTION_BRANCH, __ACCEPT
      .long   R_FETCH, EMIT, SPACE, R_FROM, EMIT, ONE_MINUS
      .long   BRANCH, _ACCEPT
____ACCEPT:   .long   R_DROP, NIP, MINUS, NEGATE, CR
      .long   EXIT

// : QUERY  TIB C/L ACCEPT #TIB ! >IN 0!  ;
QUERY:      THREAD            // QUERY   CORE EXT
      .long   T_I_B, C_SLASH_L, ACCEPT, NUMBER_T_I_B, STORE
      .long   TO_IN, ZERO_STORE
      .long   EXIT

__vectored_fast_p0:            // UART interrupt
      subi   r0,   12
      stm   r13-r15,(r0)
      lrw   r14,   [SCICR]
      ldb   r13,   (r14, 0xB)
      bsr   UART_
UART:      .short   0
UART_:      ldb   r14,   (r15, 1)   // head
      bseti   r14,   20
      stb   r13,   (r14)
      addi   r14,   1
      andi   r14,   0x1F
      stb   r14,   (r15, 1)
      ldm   r13-r15,(r0)
      addi   r0,   12
      rfi

_UART_:      .long   UART