Бэкфорт в примерах, местами даже полезных.

profiT

Код:

\ Пример: создание нескольких слов во время исполнения через
\ DOES> внутри START{ ... }EMERGE

REQUIRE START{ ~profit/lib/bac4th.f

: ABC-VOC ( "name -- )
CURRENT @
VOCABULARY 
LAST @ NAME> ALSO EXECUTE DEFINITIONS
S" a" CREATED
START{ DOES> DROP  CR S" a" TYPE }EMERGE
S" b" CREATED
START{ DOES> DROP  CR S" b" TYPE }EMERGE
S" c" CREATED
START{ DOES> DROP  CR S" c" TYPE }EMERGE
PREVIOUS SET-CURRENT ;

ABC-VOC abc

ALSO abc
a b c

ygrek

А вот ещё такое применение отката. Для записи xml (и иже с ними) тэгов. На прямом ходе выводится открывающий тэг, при откате - закрывающий.

Запись S" a" tag S" c" tag S" d" tag сгенерирует вложенные тэги
<a><c><d></d></c></a>
Чтобы получить тэги на одном уровне их надо перебирать с помощью *> <*> <* или PRO CONT
S" a" tag PRO S" c" tag CONT S" d" CONT ;
или
S" a" tag *> S" c" tag <*> S" d" <*
даст
<a><c></c><d></d></a>

Тэги с атрибутами (пока?) не понятно как красиво сделать.

Код:

REQUIRE PRO ~profit/lib/bac4th.f
REQUIRE STR@ ~ac/lib/str5.f
: tag
   2DUP
   PRO
   " <{s}>" STYPE
   BACK " </{s}>" STYPE TRACKING
   CONT
   ;

И пример

Код:

0 VALUE counter
: inner=> PRO 
   3 0 DO
   counter " inner{n}" DUP STR@ CONT STRFREE
   counter 1+ TO counter 
   LOOP ;
: sub=> PRO S" sub1" CONT S" sub2" CONT ;
: start
   S" start" tag sub=> tag inner=> tag " {counter DUP *}" STYPE ;

Вывод :

Код:

<start>
 <sub1>
  <inner0>0</inner0>
  <inner1>1</inner1>
  <inner2>4</inner2></sub1>
 <sub2>
  <inner3>9</inner3>
  <inner4>16</inner4>
  <inner5>25</inner5></sub2></start>

profiT

Цитата:

Тэги с атрибутами (пока?) не понятно как красиво сделать.

Смотря как представлять атрибуты... Если упростим для этого данного случая, можно выводить строкой:

Код:

\ REQUIRE MemReport ~day/lib/memreport.f

REQUIRE PRO ~profit/lib/bac4th.f
REQUIRE LOCAL ~profit/lib/static.f
REQUIRE STR@ ~ac/lib/str4.f

: STR> ( s --> addr u \ <-- ) PRO BACK STRFREE TRACKING RESTB STR@ CONT ;
: >STR ( addr u --> s \ <-- ) PRO BACK STRFREE TRACKING "" RESTB STR+ CONT ;


: attrTag ( addrA uA addrT uT s -- ) PRO
LOCAL s s ! \ s -- строка, куда кидаем вывод
BACK " </{s}>" STR> s @ STR+ TRACKING
2RESTB " <{s} {s}>" STR> s @ STR+
CONT ;

: tag ( addrT uT s -- ) PRO >R S" " 2SWAP R> attrTag CONT ;

0 VALUE txt

: html
"" TO txt
START{
S" html" txt tag
S" background=white" S" body" txt attrTag
S" b" txt tag
S" bolded" txt STR+
}EMERGE
txt STYPE ;
html

\ MemReport

profiT

А вот ещё одна штукенция: ~profit/lib/bac4th-sequence.f.

Делить строки на слова уже умеем. А вот выявить общее слово в обоих строках?

Код:

REQUIRE split-patch ~profit/lib/bac4th-str.f
REQUIRE seq{ ~profit/lib/bac4th-sequence.f
REQUIRE COMPARE-U ~ac/lib/string/compare-u.f

: cross-str PRO (: 2OVER 2OVER COMPARE-U 0= ;) cross CONT ;

: commonWord
seq{ S" kiwi apple lemon orange"
BL byChar split-patch }seq2 ( list-xt1 )
seq{ S" peach cherry lemon kiwi feyhoa"
BL byChar split-patch }seq2 ( list-xt1 list-xt2 )
cross-str 2DUP TYPE SPACE ;

CR commonWord
\ должно выйти: kiwi lemon 

Неплохо, а? Причём, такая задача (определение общих элементов в двух структурах, или разница двух множеств, например для синхронизации чего-либо) потянуло за собой создание отдельного вида чего-то-вроде-списка в виде динамически генерируемого итератора.

Более полные примеры можно посмотреть в самой библиотеке.

(уфф.. Ажно голова гудит, весь день, запоем, копался)

mOleg

кррасиво! Ж8)

profiT

В ходе вчерашнего обсуждения в чате нарисовал диаграмму работы бэкфортового факториала, не пропадать же добру:

Код:

: FACT ( n -- !n ) *{ INTSTO 1+ DUP }* ;

И диаграмма: http://files.myopera.com/profiT/files/fact-bac4th.svg

in4

А вот такое можно сделать (реализовать

)?
Надо найти в cvs ссылки на отсутствующие файлы.
Пока ИМХО достаточно проверять:

исходники .f на наличие файлов (и определений в них) в REQUIRE/REQUIRED
наличие слов INCLUDE/INCLUDED(а потом и заданного списка слов из файла)- это уже для чистки исходников
.bat на наличие команд, отличных от списка встроенных команд(список тоже можно из файла)
и обходить дерево каталогов, начиная с указанного каталога
иметь возможность результаты работы фильтровать, форматировать и записывать в файл(ы)

Неочевидную продвинутую оптимизацию пока не затрагиваем - это реальный учебный пример...

profiT

in4 писал(а):

Неочевидную продвинутую оптимизацию пока не затрагиваем - это реальный учебный пример...

Это не учебный пример. Это достаточно большая программа. Да и bac4th тут особенно не к чему будет прикрутить..

profiT

Кто думают что итераторы могут рефакторизировать только линейные циклы могут посмотреть на bac4th-итератор двоичного поиска fork-cycle и определённую через него процедуру reverse-function (~profit/lib/binary-search.f), которая находит обратные функции от функций с одним аргументом:

Код:

: 10/ ( res -- x )
0 SWAP DUP \ задаём область поиска аргумента x, при котором f(x)=res
DROPB \ снимаем флаг прямого попадания по окончании работы reverse-function
reverse-function
10 * ; \ функция от которой берём обратную

Или можно искать квадратные корни так (слово factor -- из ~profit/lib/bin-mul.f):

Код:

: sqrt
DUP MAX{ factor DUP }MAX \ находим максимальную степень двойки в числе
2/ \ берём от неё квадратный корень, т.е. делим степень на два
defactor \ переводим из экспоненциального вида к обычному, т.е. возводим в степень
DUP 2* \ формируем диапазон в котором находится корень числа
ROT DROPB reverse-function DUP * ;

Или даже целочисленно делить:

Код:

: // ( a b -- a/b )
OVER -ROT ( a a b )
LOCAL b DUP b !
MAX{ factor DUP }MAX 1+
RSHIFT DUP 2*
ROT DROPB reverse-function b @ * ;

Хотя конечно, именно эти примеры сами по себе никакого практического смысла не имеют. Но в ~profit/prog/sort/sort.f может пригодится чтобы убрать хотя бы одну из трёх генерируемых функций (две -- для сортировки, одна -- для двоичного поиска).

Кроме того, fork-cycle демонстрирует и ещё одну особенность: управление ходом итератора (цикла) из подчинённого (внешнего) слова. Такой же принцип показан в ~profit/misc/variableStepIterating.f для линейных циклов по диапазону с переменным шагом.

Бэкфорт в примерах, местами даже полезных.

Кто сейчас на конференции