Удобные слова

вопрос

Как сделать такое:
вместо того, чтобы опеределение переменной давало одну переменную, типа
: VARIABLE CREATE , DOES> ;
жеательно, чтобы оно опеределяло несколько слов одновременно, я хотел бы получать слова
>СЛОВО - помещение значения в переменную
СЛОВО+ - прибавление значения к пременной,
предположим, это обработка растрового изображения по кускам или игра на квадратной доске, нужна переменная структура Y-X c легкоизменяемыми в тексте значениями.

я могу создать это так:
variable CELL 4 CELL !

: 2DIM ( ... ENSIONS ) ( INITIAL_X INITIAL_Y --> VARIABLE_DIMENTIONS )
CREATE HERE ( INITIAL_X INITIAL_Y HERE )
! CELL @ ALLOT ( INITIAL_X )
HERE ! CELL @ ALLOT ( ИЛИ ЗАПЯТЫМИ ВСЁ ЭТО )
( STACK IS EMPTY )
DOES> DUP @ swap CELL @ + @ ( x y ) ;

такое слово создаёт структуру и инициализирует её первичными значениями INITIAL_X INITIAL_Y
затем при вызове слова
INITIAL_X INITIAL_Y 2DIM СЛОВО
СЛОВО ( --> INITIAL_X INITIAL_Y )
мы получаем значения на стеке.
Но как сделать, чтобы ОДНОВРЕМЕННО ОБРАЗОВЫВАЛИСЬ СЛОВА
+СЛОВО и >СЛОВО ?

т.е.
чтобы одновременно образовывалсь 3 слова
: 2DIM
CREATE ( И ТУТ ОБРАЗУЕТСЯ ПЕРВОЕ СЛОВО ) DOES>
CREATE ( И ТУТ ОБРАЗУЕТСЯ СЛЕДУЮЩЕЕ +СЛОВО ) DOES>
CREATE ( И ТУТ ОБРАЗУЕТСЯ >СЛОВО ) DOES> ;

Icefall

Все можно сделать. Генерится строка и скармливается EVALUATE или EVALUATE-WITH, точно не помню. Но это лишнее.

Вместо того, чтобы мусорить в словаре однотипными словами, лучше написать лексикон. Пример (работа с изображениями (SPF)):

Код:

0 VALUE Xsize
0 VALUE Ysize
0 VALUE buffer
...
: PICTURE  ( x y )  CREATE  SWAP W, W, 0 , ;
: >XY   ( pic -- x y )  DUP W@ SWAP 2+ W@ ;
: >addr ( pic -- addr )  CELL+ @ ;
: /Picture  ( pic -- size )  >XY * CELLS ;
: Picture{  ( pic )  DUP /Picture  GET-MEM SWAP CELL+ ! ;
: }Picture  ( pic )  >addr FREE-MEM ;
: Picture!  ( pic )  DUP >XY  TO Ysize  TO Xsize
    CELL+ @  TO buffer ;
: Clear     ( pic )  DUP  >addr  SWAP /Picture  ERASE ;
: Pixel  ( x y -- addr )  Xsize * CELLS buffer + ;
: PutPixel  ( RGB x y -- )  Pixel ! ;
: GetPixel  ( x y -- RGB )  Pixel @ ;

Используется:

Код:

20 30 PICTURE sprite
640 480 PICTURE screen
sprite Picture{
screen Picture{

sprite Picture!
0x102030 40 50 PutPixel
40 50 GetPixel .

screen Picture!
: horline   400 0 DO 0xFFFFFF 20 I PutPixel LOOP ;
horline

sprite Clear

sprite }Picture
screen }Picture

Icefall

вопрос писал(а):

чтобы одновременно образовывалсь 3 слова
: 2DIM
CREATE ( И ТУТ ОБРАЗУЕТСЯ ПЕРВОЕ СЛОВО ) DOES>
CREATE ( И ТУТ ОБРАЗУЕТСЯ СЛЕДУЮЩЕЕ +СЛОВО ) DOES>
CREATE ( И ТУТ ОБРАЗУЕТСЯ >СЛОВО ) DOES> ;

В таком виде работать не будет. 2DIM определит только одно слово, которое будет определяющим для +СЛОВА, которое, в свою очередь будет определяющим для >СЛОВА.

вопрос

Icefall писал(а):

Вместо того, чтобы мусорить в словаре однотипными словами, лучше написать лексикон.

Если кодируешь что-то сложное , то лишь бы сам понял -- не до "мусорить".

Mihail

Icefall писал(а):

вопрос писал(а):

чтобы одновременно образовывалсь 3 слова
: 2DIM
CREATE ( И ТУТ ОБРАЗУЕТСЯ ПЕРВОЕ СЛОВО ) DOES>
CREATE ( И ТУТ ОБРАЗУЕТСЯ СЛЕДУЮЩЕЕ +СЛОВО ) DOES>
CREATE ( И ТУТ ОБРАЗУЕТСЯ >СЛОВО ) DOES> ;

В таком виде работать не будет. 2DIM определит только одно слово, которое будет определяющим для +СЛОВА, которое, в свою очередь будет определяющим для >СЛОВА.

Конечно можно сделать больше одного DOES> в определении
(определив спец средства), но не очень нужно.
Можно определить отдельные определяющие слова,
затем вставить их в одно.

Код:

: 2, HERE 2! 2 CELLS ALLOT ;

: 2DIM: ( ... ENSIONS ) ( INITIAL_X INITIAL_Y --> VARIABLE_DIMENTIONS )
CREATE 2,
DOES> 2@ ;

: 2DIM+ ( pfa -- )
CREATE ,
DOES> @ DUP >R 2@ D+ R> 2! ;

: 2DIM  ( INITIAL_X INITIAL_Y --> )
 
  2DIM: HERE CELL- CELL- 
  DUP 2DIM+
  CREATE ,
  DOES> @ 2! ;

\ test 
  
6 7 2DIM СЛОВО +СЛОВО >СЛОВО

СЛОВО . .  

 -2 3 +СЛОВО

СЛОВО . .

 7 8 >СЛОВО

СЛОВО . .

profiT

Только сегодня утром почитал эту тему. Во-первых, по изначальной задаче (несколько CREATE DOES>) я давал решение. Во-вторых, постановка задачи похожа на то что нужно построить свою собственную VALUE-переменную.. В третьих... В третьих лучше в конце.

Вспомним, что VALUE-переменные сразу выдают значения при их прямом вызове, записывают значения при вызове с TO , и прибавляют их при вызове с +TO (есть ещё AT , но тут его не спрашивали, да и в ядре SPF его нету).

Смотрим описание VALUE в ядре (можно за компанию и VECT посмотреть)

Код:

: VALUE ( x "<spaces>name" -- )
  HEADER
  ['] _CONSTANT-CODE COMPILE, ,
  ['] _TOVALUE-CODE COMPILE,
;

Становится понятно что в SPF VALUE-переменные сделаны хитровато:

Код:

заголовок|CALL _CONSTANT-CODE|ячейка переменной|CALL _TOVALUE-CODE
         |     5 байт        |   4 байта       |   5 байт

Основываясь на этой схеме и посмотрев как ygrek уже делал свои VALUE-переменные (двойные): ~ygrek/lib/2value.f (или мой вариант, без дополнительного слова 2TO , ~profit/misc/2value.f), можно, по аналогии, построить похожую структуру но с ещё одним исполняемым полем, для +TO (только слово +TO лучше назвать как нибудь по-другому, из-за того что оно на самом деле, будет делать не что ожидается).

Или пришёл в голову ещё один способ: через NOTFOUND , как сделана форма вызова словарь::слово.

А теперь, в-третьих: бесмысленно это. Icefall всё правильно сказал: строить свой лексикон и проще, и удобнее, и быстрее (как в написании, так и в исполнении), и гибче, и гигиеничней (для словаря), и "фортовей", т.е. ты не будешь создавать на ровном месте новое правило синтаксиса.

chess

profiT писал(а):

А теперь, в-третьих: бесмысленно это. Icefall всё правильно сказал: строить свой лексикон и проще, и удобнее, и быстрее (как в написании, так и в исполнении), и гибче, и гигиеничней (для словаря), и "фортовей", т.е. ты не будешь создавать на ровном месте новое правило синтаксиса.

Не надо обобщать. Иногда синтаксис поменять эффективнее и Форт лучшее средство для этого.

ygrek

Приведу для полноты картины и такой вариант нескольких DOES>-ов

Код:

\ declaration :
\  SIZE bytes str
\ usage :
\ str ( -- addr SIZE )  \ data addr and total allocated size
\ str@ ( -- addr u ) \ data addr and size used at the moment
\ str! ( addr u -- ) \ copy source u bytes from addr to the array
\ str# ( uaddr -- ) \ address of the cell where the size of the array resides
\ str[] ( i -- addr ) \ give address of i-th byte

REQUIRE STR-APPEND  ~ygrek/lib/string.f

MODULE: static_arrays

: (does)   DOES> DUP 2 CELLS + SWAP @ ;
: (does@)  DOES> @ DUP CELL+ SWAP @ ;
: (does!)  DOES> @ 2DUP ! CELL+ SWAP CMOVE> ;
: (does#)  DOES> @ ;
: (does[])  DOES> @ CELL+ + ;

EXPORT

: bytes
   NextWord 
   2DUP                               CREATED ROT DUP , HERE >R 0 , ALLOT (does)
   2DUP [CHAR] @ CHAR-APPEND 2DUP  1+ CREATED R@ , (does@)
   2DUP [CHAR] ! CHAR-APPEND 2DUP  1+ CREATED R@ , (does!)
   2DUP [CHAR] # CHAR-APPEND 2DUP  1+ CREATED R@ , (does#)
   2DUP    S" []" STR-APPEND 2DUP 2 + CREATED R@ , (does[])
   2DROP RDROP ;

;MODULE

Код:

100 bytes str
 Ok
str
 Ok ( 5703560 100 )
str@
 Ok ( 5703560 100 5703560 0 )
2DROP 2DROP S" qua" str!
 Ok
str@
 Ok ( 5703560 3 )
TYPE
qua Ok

Pretorian

это что, вариант записи числа в переменную по адресу?

Код:

VARIABLE EXTRA-MEM 4000 ' EXTRA-MEM EXECUTE !

Mihail

Pretorian писал(а):

это что, вариант записи числа в переменную по адресу?

Код:

VARIABLE EXTRA-MEM 4000 ' EXTRA-MEM EXECUTE !

Во время ЦК все целевые слова заносятся в словарь TC-WL и доступны для
исполнения (это не значит, что все готовы для исполнения).
Слово ' определеное в src\tc_spf.f временно открывает TC-WL.

Код:

CR .( EM=) ' EXTRA-MEM EXECUTE .
CR .( EM=) [T]  EXTRA-MEM [I] .
CR .( EM=) ALSO TC-WL EXTRA-MEM  PREVIOUS .

Pretorian

Если честно, то ни чего не понял. Что такое целевые слова, что еще за словарь TC-WL (думал тока FORTH словарь есть в системе по умолчанию ).

Mihail

Pretorian писал(а):

Если честно, то ни чего не понял. Что такое целевые слова, что еще за словарь TC-WL (думал тока FORTH словарь есть в системе по умолчанию ).

Целевые слова - это слова, которые будут содержатся в будущей форт-системе.
Вообще, каталог spf\src содержит исходный текст самой форт-системы и
средства ее сборки. Словарь TC-WL в новой форт-системе будет
виден как FORTH.
Строка:
TC-LATEST-> FORTH-WORDLIST
в spf\src\spf.f произведет эту подмену.

В СПФ нет полной совместимости между целевой компиляцией
и работой в рантайме.

Удобные слова

Кто сейчас на конференции