A какое отношение вообще имеет выбор какого-то языка к случаю, когда выбор сделан изначально, и этот выбор - Форт?



Это называется, "что попросил - то и получил!" (c)...
Я не видел слова 'универсальный' в постановке вопроса.

мой вариант

\ 18-05-2007 ~mOleg
\ Copyright [C] 2006-2007 mOleg mininoleg@yahoo.com
\ решение задачи с конкурса открытого на форуме
\ преобазование символов табуляций в пробелы и обратно

\ -- полезные слова ---------------------------------------------------------

\ добавить число к находящемуся на стеке возвратов
: R+ ( r: a d: b --> r: a+b ) 2R> -ROT + >R >R ;

\ резервировать на HERE n байт памяти, заполнить их байтом char ?
: ALLOTFILL ( n char --> ) HERE OVER ALLOT -ROT FILL ;

\ выравнять число base на указанное значение n ?
\ граница выравнивания произвольная.
\ выравнивание производится в большую сторону
: ROUND ( n base --> n ) TUCK 1 - + OVER / * ;


   0x09 CONSTANT tab_  \ код символа табуляции

\ -- формирование результирующей строки -------------------------------------

        USER-VALUE buffer  \ адрес временного буфера
        USER-VALUE out>    \ позиция с которой можно добавлять данные в буфер

     20 CONSTANT tab-limit \ предельный размер табуляции

   CREATE spaces_ tab-limit BL ALLOTFILL \ строка пробелов

\ добавление в буфер строки asc # к уже имеющимся
: >out ( asc # --> ) DUP IF out> SWAP 2DUP + TO out> CMOVE ELSE 2DROP THEN ;
: c>out ( char --> ) out> TUCK C! 1 CHARS + TO out> ;

\ вывести в буфер указанное кол-во пробелов
: gap ( # --> ) spaces_ SWAP tab-limit UMIN >out ;

\ получить адрес и длинну собранной в буфере строки
: result> ( --> asc # ) buffer out> OVER - ;

\ освобождение буфера
: free-result ( --> ) buffer IF buffer FREE THROW 0 TO buffer THEN ;

\ инициализация буфера
: init-buffer ( # --> )
              free-result
              CELLS ALLOCATE THROW
              DUP TO buffer TO out> ;

\ -- преобразование табуляций в пробелы -------------------------------------

\ посчитать количество пробелов на одну табуляцию для указаной позиции
: space# ( pos tab# --> spaces )
         TUCK OVER >R ROUND R> -
         DUP IF NIP ELSE DROP THEN ;

\ выделить из строки подстроку, оканчивающуюся указанным символом
: piece ( src # char --> res # )
        >R OVER + OVER
        BEGIN 2DUP <> WHILE       \ пока есть символы в строке
              DUP C@ R@ <> WHILE  \ пока символ не найден
            1 CHARS +
          REPEAT
        THEN RDROP NIP OVER - ;

\ разделить строку на две подстроки по символу char
: split ( src # char --> rest # res # )
        >R 2DUP R> piece TUCK 2>R - NIP 2R@ + SWAP 2R> ;

\ позиция последнего символа в выходном буфере
: pos ( --> u ) out> buffer - ;

\ преобразовать одиночную строку,
\ содержащую символы табуляции в строку с пробелами
: tabs>spaces ( src # tab# --> res # )
              OVER init-buffer >R
              BEGIN tab_ split >out  DUP WHILE
                    pos R@ space# gap
                  SKIP1
              REPEAT RDROP 2DROP result> ;

\ -- преобразование пробелов в табуляции ------------------------------------

        USER inpos \ текущая позиция

\ посчитать количество пробелов от начала строки
: count-spaces ( asc # --> res # n )
               0 >R OVER + SWAP
               BEGIN 2DUP <> WHILE     \ пока не конец строки
                     DUP C@ BL = WHILE \ пока пробелы
                   1 R+ 1 CHARS +
                 REPEAT
               THEN TUCK - R> ;

\ преобразовать пробелы, если возможно в табуляции
: convert-spaces ( pos n tab# --> )
                 >R BEGIN DUP WHILE
                          OVER R@ space#  2DUP < 0= WHILE
                          DUP inpos +!
                          TUCK - >R + R>
                        tab_ c>out
                      REPEAT SWAP DUP inpos +! gap
                    THEN RDROP 2DROP ;

\ преобразовать одиночную строку src #, содержащую пробелы
\ в строку содержащую табуляции вместо подходящих длинных
\ последовательностей пробелов.
: spaces>tabs ( src # tab# --> res # )
              OVER init-buffer >R  0 inpos !
              BEGIN BL split DUP inpos +! >out  DUP WHILE
                    count-spaces inpos @
                    SWAP R@ convert-spaces
              REPEAT RDROP 2DROP result> ;

\ EOF -- тестовая секция ----------------------------------------------------

\ загрузить содержимое файла в буффер
: source ( FileName # --> addr # )
         R/O OPEN-FILE THROW >R
           R@ FILE-SIZE THROW DROP
              DUP ALLOCATE THROW
           TUCK SWAP R@ READ-FILE THROW
         R> CLOSE-FILE THROW ;

S" sample.txt" source  \ любой однострочный текст
              2DUP TYPE 2DUP DUMP CR
8 tabs>spaces 2DUP TYPE 2DUP DUMP CR
8 spaces>tabs 2DUP TYPE DUMP CR

Ну, вот сейчас /me нечто подобное и делает Просто искать наиболее подходящий язык для каждой функции чисто из спортивно-религиозного интереса....

Я не понял, в чем проблема?
Задачка реальная и достаточно простая - тут один товарищь говорил, что вообще не стоит столь простую задачу публиковать, так как ну уж слишком она простая

Я лично решал в лоб, и не долго мучился. Мой код уже работает в другом месте, куда меня это дело уже давно просили вставить

a) б)
Я конечно, немного извиняюсь. Но и в первом, и во втором примерах промежуточные строки в памяти создаются и снимаются "автоматом". А теперь найдите в обоих кодах хоть намёк на ALLOCATE или FREE, их нет, только в первом примере, и из-за постановки задачи пришлось HEAP-COPY применить. Управление памятью в обоих случаях там спрятано в "обёртках", которые собственно для того и писались (в том числе и мной).

в) Первый пример немножко на бэкфорте написан.

г) Второй пример немножко на конечных автоматах сделан.

Не из спортивного, а из педагогического. Я понимаю, что и постановка задачи, и ее решение должны быть образцовыми.

Не надо снова съезжать с темы в дешевые хохмы.
Если, по-вашему, все задачи имеют решение, прошу предоставить решение и той, что написал я. Или признайте, что ваше утверждение ложно.

Что меня немного удивляет в вашем решении, так это необходимость работы со всем файлом сразу. Обычно такие вещи делаются построчно, чтобы не было проблем с очень большими файлами.

A смысл этого признания есть, если вы юмора не понимать?

Да, я прекрасно осознавал, когда писал,
что моя фраза про "все задачи имеют решение" - неверна.
хотя, подразумевалось "все задачи предложенные на данном конкурсе".

а откуда взялось такое впечатление?
На самом деле там как раз построчно. Просто файл может состоять из одной строки

Для тренировки навыков это подойдет. Но для целостного понимания проблем разработки - не очень. Новый язык - это совершенно объективное время на его освоение, затраты на приобретение, косвенные затраты на интеграцию. Почему-то слова "я не знаю языка XXX" вызывают реакцию "так иди и изучи!", а не "хм, да, извините, что предложили вариант, который потребует дополнительного повышения квалификации".

Если я правильно понял, речь идет о преобразовании одного объекта - точки Line в другой - фрагмент Cell.
Может я ошибаюсь, но стандартными средствами этого сделать нельзя.
Какой в этом смысл? Не проще просто поставить новый фрагмент на эту точку?

Универсальное решение :

А вот так правильно

Тогда не ответил, сейчас отвечу.

Вот пример того, как можно сформулировать условие задачи так, что его можно понять
с точностью наоборот. Предположим вы вызвали текст алгоритма по EVALUATE.

Тогда в моем понимании :
Если возврата из EVALUATE нет, то алгоритм остановился, ибо завис (например, впав в бесконечный цикл). Если возврат есть, то алгоритм не остановился, ибо не завис и успешно завершился.

В понимании dynamic-wind :
Если возврата из EVALUATE нет, то алгоритм не остановился ибо ещё продолжает что-то считать. Если возврат есть, то алгоритм остановился ибо завершил свою работу.

Мораль :
А формулируйте-ка условия задач так, чтобы их нельзя было понять ИНАЧЕ.