\ Файл:       replace.spf
\ Автор:      VoidVolker
\ Дата:       08/12/2009 17:21
\ Версия:     3.00, версия ннКрона 1.91.1083
\ Описание:
\ Утилита для командной строки, позволяющая для каждого файла с указанной маской заменить искомую строку на указанную.

\ Инструкция пользователя:
\   -p "path"- путь к каталогу, в котором должны искаться файлы для замены строк
\     (наличие слеша в конце обязательно, иначе будет считаться частью маски);
\   -m "*.*" - маска или
\   -m "/regexp/" - регулярное выражение, идентифицирующее файл в котором должны быть произведены замены;
\   -rec - работать с подкаталогами(по умолчанию);
\   -norec - не работать с подкаталогами;
\   -s "строка1"- искомая строка, которую надо искать и заменить;
\   -r "строка2" - строку которую надо вставить вместо искомой;
\   -h - вывод подсказки по использованию утилиты.
\ Поддерживаются следующие эскейп-последовательности:
\     //  ->  /
\     /p  ->  %
\     /q  ->  "
\     /t  ->  <табуляция> 9
\     /v  ->  <вертикальная табуляция> 0xB
\     /r  ->  <возврат картеки>  0xD
\     /n  ->  <перевод строки> crlf  0x0D0A

REQUIRE AUTOSTRINGS-MODULE plugins\Autostrings.spf  \ http://www.nncron.ru/forums/viewtopic.php?f=5&t=10296#p23848

: StringReplace { a1 u1 a2 u2  a3 u3 \ rest a4 u4 buf -- a u }  \ Заменить в строке 1 подстроку 2 на строку 3, на стеке останется измененая строка
  AT buf TO a4
  a1 u1
  BEGIN OVER SWAP a2 u2 SEARCH WHILE
    TO rest SWAP 2DUP - a4 u4 2SWAP S+ TO u4 TO a4
    a3 u3 a4 u4 2SWAP S+ TO u4 TO a4
    rest u2 /STRING
  REPEAT
  a4 u4 2SWAP S+
  ROT DROP
;

VECT <vp>
VECT <vs>
VECT <vr>
VECT <vm>

VARIABLE ready?

: S"" S" " ;

: *mask S" *" ;

: init
  ['] ModuleDirName TO <vp>
  ['] S"" TO <vs>
  ['] S"" TO <vr>
  ['] *mask TO <vm>
  ready? OFF
  RECURSIVE
;

: get-str
  BL SKIP
  [CHAR] " SKIP
  BL SKIP
  [COMPILE] "
; IMMEDIATE

: :str
  :NONAME [COMPILE] get-str [COMPILE] ;
;

: is-regexp?   \ ( a u -- ? )
  OVER C@ [CHAR] / =
  SWAP ROT
  + 1- C@ [CHAR] / =
  OR
;


CREATE "help 1500 ALLOT
  S""
  " Инструкция пользователя:/n  -p /qpath/q - путь к каталогу, в котором должны искаться файлы для замены строк/n" S+
  "     (наличие слеша в конце обязательно, иначе будет считаться частью маски);/n" S+
  "   -m /q*.*/q - маска или/n" S+
  "   -m /q//regexp///q - регулярное выражение, идентифицирующее файл в котором должны быть произведены замены;/n" S+
  "   -rec - работать с подкаталогами(по умолчанию);/n" S+
  "   -norec - не работать с подкаталогами;/n" S+
  "   -s /qстрока1/q - искомая строка, которую надо искать и заменить;/n" S+
  "   -r /qстрока2/q - строку которую надо вставить вместо искомой;/n" S+
  "   -h - вывод подсказки по использованию утилиты;/n" S+
  " Поддерживаются следующие эскейп-последовательности:/n" S+
  "     ////  ->  ///n" S+
  "     //p  ->  /p/n" S+
  "     //q  ->  /q/n" S+
  "     //t  ->  <табуляция> 9/n" S+
  "     //v  ->  <вертикальная табуляция> 0xB/n" S+
  "     //r  ->  <возврат картеки>  0xD/n" S+
  "     //n  ->  crlf  0x0D0A/n" S+
  SWAP OVER "help SWAP CMOVE

\ len
: -h   \ ( -- )
  "help LITERAL MsgBox
;


: replace-in-files   \ ( -- )
  FILESONLY
  <vm> is-regexp?
    IF
      <vp> S" *" S+ FOR-FILES
        FOUND-FULLPATH <vm> RE-MATCH
          IF
            FOUND-FULLPATH FILE <vs> <vr> StringReplace
            FOUND-FULLPATH FWRITE
          THEN
      ;FOR-FILES
    ELSE
      <vp> <vm> S+ FOR-FILES
        FOUND-FULLPATH FILE <vs> <vr> StringReplace
        FOUND-FULLPATH FWRITE
      ;FOR-FILES
    THEN
;

: -p   \ ( " path" -> )
  :str TO <vp>
;

: -s   \ ( " искомая строка" -> )
  :str TO <vs>
  ready? @
    IF
      replace-in-files
      ready? OFF
    THEN
  ready? ON
;

: -r   \ ( " вставляемая строка" -> )
  :str TO <vr>
  ready? @
    IF
      replace-in-files
      ready? OFF
    THEN
  ready? ON
;

: -m   \ ( " mask|regexp" -> )
  :str TO <vm>
;

: -rec   \ ( -- )
  FF-RECURSIVE? ON
;

: -norec   \ ( -- )
  FF-RECURSIVE? OFF
;


WARNING @ WARNING OFF
: NOTFOUND ( a u -- )
  2DUP 2>R ['] NOTFOUND CATCH
  IF
     2DROP " Ошибка в строке:/n%SOURCE%" MsgBox
    BYE
  THEN
  RDROP RDROP
; WARNING !

' init MAINX !
S" replace.exe" SAVE
BYE

nncron.exe replace.spf

nncron.exe : replace  FOR-FILES: "path\*.f"  FOUND-FULLPATH FILE S" исходная строка" S" вставляемая строка" StringReplace  FOUND-FULLPATH FWRITE  ;FOR-FILES ; replace